Bedienungsanleitung der Oberﬂäche – Tonnetz

| | | | | |

10.1. Tonnetz

Das folgende Programm realisiert bereits eine recht komplizierte Umstimmungslogik. Es ist die Umsetzung einer Idee, die Martin Vogel in seinem Buch „Die Lehre von den Tonbeziehungen“ erwähnt: Es soll erkennen, in welcher Tonart gerade musiziert wird, und in der entsprechenden Tonart rein stimmen. Als Indizien für die Bestimmung der Tonart werden die Dur-Tonika, die Tonika-Parallele sowie der Dominantseptakkord herangezogen. Für harmonisch einfache Stücke ist dies ausreichend.

Die Fundamentaltonleiter wird, ausgehend vom Grundton, mit Hilfe der reinen Intervalle Oktave, Quint und Terz konstruiert.

Programm:

INTERVALL
    Oktave = 2:1
    Quint = 3:2
    Terz = 5:4

TON
    a = 440
    c = a + Quint - Terz - Oktave
    d = c + Quint + Quint - Oktave
    e = c + Terz
    f = a - Terz
    g = c + Quint
    h = g + Terz
    b = f - Quint + Oktave
    es = g - Terz
    as = c - Terz + Oktave
    des = as - Quint
    fis = d + Terz

TONSYSTEM
    C_Dur = 60 [c,des,d,es,e,f,fis,g,as,a,b,h] Oktave

UMSTIMMUNG
    Transpo (x) = @ + x [ ]

HARMONIE
    Dur = {0,4,*7}
    Moll = {0,4,9}
    Dom7 = {*2,5,7,11}

LOGIK
    TonNetz Taste N = C_Dur
    [
        FORM Dom7 -> Transpo ( ABSTAND )
        FORM Dur -> Transpo ( ABSTAND )
        FORM Moll -> Transpo ( ABSTAND )
    ]

| | | | | |